@echo off
chcp 65001 >nul
title DoTIon TV - ativar modo travado
echo.
echo  DoTIon TV - modo travado (TV box Android)
echo  ------------------------------------------
echo  Antes: aparelho restaurado de fabrica, SEM conta Google,
echo  com "Depuracao USB / pela rede" ligada nas Opcoes do desenvolvedor
echo  e na mesma rede Wi-Fi deste computador.
echo.
set /p IP=Digite o IP da TV box (Configuracoes - Rede - ex.: 192.168.0.50): 
if "%IP%"=="" goto fim
set D=%TEMP%\dotion-adb
if not exist "%D%\platform-tools\adb.exe" (
  echo Baixando as ferramentas do Android...
  mkdir "%D%" 2>nul
  curl -sSLo "%D%\pt.zip" https://dl.google.com/android/repository/platform-tools-latest-windows.zip || goto erro
  tar -xf "%D%\pt.zip" -C "%D%" || goto erro
)
set ADB="%D%\platform-tools\adb.exe"
echo Conectando em %IP% ... (aceite o aviso "Permitir depuracao" que aparece na TV)
%ADB% connect %IP%:5555
timeout /t 8 >nul
%ADB% -s %IP%:5555 get-state || goto erro
echo Baixando e instalando o DoTIon TV...
curl -sSLo "%D%\dotion-tv.apk" https://dotion.com.br/tv-apps/dotion-tv.apk || goto erro
%ADB% -s %IP%:5555 install -r "%D%\dotion-tv.apk" || goto erro
echo Ativando o modo travado...
%ADB% -s %IP%:5555 shell dpm set-device-owner br.com.dotion.tv/.AdminReceiver || goto erro
%ADB% -s %IP%:5555 shell am start -n br.com.dotion.tv/.MainActivity
echo.
echo  PRONTO! O DoTIon TV abriu travado. Agora e so parear com o codigo que aparece na TV.
echo  Para mexer no aparelho depois: pagina da TV no portal - "Destravar 15 min".
goto fim
:erro
echo.
echo  Nao deu certo. Confira: TV sem conta Google (restaure de fabrica), depuracao ligada,
echo  mesma rede, e aceite o aviso na TV. Depois rode de novo.
:fim
echo.
pause